How to include individual PBC box dimensions in xyz file format compatible with VMD

Question

I am using ASE to write an xyz file. Each frame in the file has a different PBC (periodic boundary condition). Currently, a frame starts like this:

192
Lattice="23.46511 0.0 0.0 0.0 23.46511 0.0 0.0 0.0 23.46511" Properties=species:S:1:pos:R:3:force:R:3 TotEnergy=-1103.24236 cutoff=-1.0 nneightol=1.2 pbc="T T T"
O       11.72590000      14.59020000       1.86929000      -0.04213780       0.03788820       0.00314949
H       12.69400000      16.13880000       1.25499000      -0.03709700      -0.03453660       0.01566490

The lattice coordinates are what I want to use as the PBC box. However, when I try to visualize this file in VMD, it throws the following error and doesn't show the box:

vmd > pbc box
ERROR) Suspicious pbc side length (a=0.000000 b=0.000000 c=0.000000). Have you forgotten to set the pbc parameters?

What should be done to include a,b,c in the xyz file so that it is compatible with pbc box in VMD?

Answer 1

That is a modification of the standard XYZ file format and is called extended XYZ format, and not all programs are compatible with it.

From the VMD Molfile Plugin Documentation page, it looks that VMD is only compatible with standard XYZ format.

Also, take a look at this answer (to another question) about adding PBC info in VMD after loading standard XYZ file.

Answer 2

Camps is correct, VMD cannot directly parse the comment line of an xyz file because the extended ASE format is not recognized. You can, however, use a tcl-script to load the file and parse the comment line yourself. I am no tcl expert but here is an example that works for me:

set filename [lindex $argv 0]
    
# load the coordinates into vmd
mol new $filename waitfor all
    
# open the file to parse the lattice vectors
set file [open $filename]
    
set i 0
    
while {[gets $file line] >= 0} {
  # get the lines containing Lattice="
  if {[regexp {Lattice=\"[ 0-9\.\-eE]*} $line lattice]} {  
    # extract the numbers from the line into v_arr
    set vectors [regexp -all -inline {\S+} [lindex [split $line \"] 1]]
    set j 0     
    foreach v $vectors {
      set v_arr($j) $v
      incr j
    }
    # set the pbc for the i-th frame
    # uncomment the second line if the cell is not orthorhombic
    pbc set "{$v_arr(0) $v_arr(4) $v_arr(8)}" -first $i -last $i
    #pbc set "{{$v_arr(0) $v_arr(1) $v_arr(2)} {$v_arr(3) $v_arr(4) $v_arr(5)} {$v_arr(6) $v_arr(7) $v_arr(8)}}" -namd -first $i -last $i
    incr i
  }
}
    
close $file

Save the code into a file "pbc.tcl". You can then invoke the script by running

vmd -e pbc.tcl -args trajectory.xyz

This will automatically load the coordinates and parse the lattice vectors from trajectory.xyz. The -e flag signals vmd to execute the code within pbc.tcl and passes the -args to the script.